Jak spustit aplikaci a čekat na její ukončení ve VB

Private Declare Function WaitForSingleObject _
        Lib "kernel32" _
        (ByVal hHandle As Long, _
         ByVal dwMilliseconds As Long) As Long

Private Declare Function CloseHandle _
        Lib "kernel32" _
        (ByVal hObject As Long) As Long
   
Private Declare Function OpenProcess _
        Lib "kernel32" _
        (ByVal dwDesiredAccess As Long, _
         ByVal bInheritHandle As Long, _
         ByVal dwProcessId As Long) As Long


Private Const INFINITE = -1
Private Const SYNCHRONIZE = &H100000


Function SpustACekej(ByVal sAppRun As String) _
         As Boolean
  Dim lTask As Long
  Dim lRet As Long
  Dim lHandle As Long

  On Error GoTo FncErr
  
  lTask = Shell(sAppRun, vbNormalFocus)
  lHandle = OpenProcess(SYNCHRONIZE, False, lTask)
  lRet = WaitForSingleObject(lHandle, INFINITE)
  lRet = CloseHandle(lHandle)
  SpustACekej = True
  Exit Function
FncErr:
SpustACekej = False
End Function

Private Sub Command1_Click()
    If SpustACekej("Notepad.exe") Then
      'Aplikace spustena a
      'dobehla v poradku
      MsgBox "OK"
    Else
      MsgBox "Chyba"
    End If
End Sub